KnowBrainer Speech Recognition
Decrease font size
Increase font size
Topic Title: Vocola commands for using Mouseless browsing with Firefox
Topic Summary:
Created On: 02/14/2015 03:17 PM
Status: Post and Reply
Linear : Threading : Single : Branch
Keyword
 02/14/2015 03:17 PM
User is offline View Users Profile Print this message


mdl
Top-Tier Member

Posts: 742
Joined: 04/18/2009



## 
## Clicking links/gizmos:
## 

# 
# These commands require the mouseless browsing extension.
# 
# Plug-in configuration:
# 
#   General->not execute automatically without pressing enter
#   ID-types->all modifiers   = ctrl+alt
#   Keys->blur active element = ctrl+DIVIDE  (press control num pad slash)
#
# Also, remove Dragon's use of DIVIDE
# 

Blur()   := {ctrl+NumKey/};
Toggle() := {NumKey.};
D(n)     := When($n,{alt+ctrl+$n});

show    numbers = Blur() Toggle();
refresh numbers = Blur() Toggle() Toggle();
blur me         = Blur();

<pick> 0..9 [0..9 [0..9 [0..9]]] = Blur() D($2) D($3) D($4) D($5) $1;

<pick> := (        pick = {shift}{enter} 
          | drop   pick = {shift}{enter}{alt+down}
          | go     pick = {shift}
          | push   pick = {shift}{ctrl+enter}    # stay but open new tab w/ link
          | tab    pick = {shift}{ctrl+shift+enter}
          | window pick = {shift}{shift+enter}
          | menu   pick = {shift}{shift+f10}
          | save   pick = {shift}{shift+f10} Wait(100) k
          | copy   pick = {shift}{shift+f10} Wait(100) a # copy URL of link
          );

# 
# These commands use the built-in quick find link:
# 

       link <_anything> = Blur() "'$1" {enter};
new    link <_anything> = Blur() "'$1" {ctrl+enter};
window link <_anything> = Blur() "'$1" {shift+enter};



 02/14/2015 03:21 PM
User is offline View Users Profile Print this message


mdl
Top-Tier Member

Posts: 742
Joined: 04/18/2009

(As written, these need Vocola 2.8.1 or later; for Vocola 3, you will need to translate the <pick> 0..9 [0..9 [0..9 [0..9]]] command into 4 separate commands.)
 02/14/2015 03:35 PM
User is offline View Users Profile Print this message


mdl
Top-Tier Member

Posts: 742
Joined: 04/18/2009

As for what the commands do,

"pick one four" clicks the link numbered 14 or activates the control numbered 14.

"tab pick 1 2 3" opens link 123 in a new tab.

"window pick 2" opens link 2 in a new window.

"push pick 7 8" opens link 78 in a new tab, but does not switch to that tab.

"go pick 6 6" selects link 66 but does not click it. Pressing shift f10
will bring up the right context menu for that link (but see also the
other pick variants that do this for you). go pick is also useful for
text boxes that immediately send their contents if you "click" them via
the normal pick.

drop pick selects a link then drops down its pulldown menu, menu pick
selects a link then pops up its menu, save pick prompts you to save the
linked page, and copy pick saves the URL of the link to the clipboard.

Show numbers toggles the mouseless browsing numbers and refresh numbers
does that twice (sometimes useful when numbers don't all show up).
 02/14/2015 03:36 PM
User is offline View Users Profile Print this message


mdl
Top-Tier Member

Posts: 742
Joined: 04/18/2009

You can find the Mouseless Browsing extension at https://addons.mozilla.org/en-us/firefox/addon/mouseless-browsing/
Statistics
30404 users are registered to the KnowBrainer Speech Recognition forum.
There are currently 5 users logged in.
The most users ever online was 3936 on 09/08/2015 at 11:44 AM.
There are currently 383 guests browsing this forum, which makes a total of 388 users using this forum.

FuseTalk Standard Edition v4.0 - © 1999-2018 FuseTalk™ Inc. All rights reserved.