Boris, the reason the macro doesn't work is simply because of the line:

GetCursorPos( p )

Just change this to

GetCursorPos p

However this macro is flawed because it doesn't give you the proper coordinates if, for example, you choose the option "upper left corner of active window" and the active window isn't positioned in the top left corner of the screen. You need to add some more Windows API functions to do this properly like in the command I gave you above. Anyway here is a working version of SW's script which is much faster as well because Sean is using HeardWord which is a very slow command. I suggest if you use this script that you only use it for screen position commands and not active window mouse position commands. If I had the time I would modify it for you but I don't and anyway you can use the other command I give you for active window mouse position commands. If for any reason the script I have posted below puts the information in the wrong place of the command wizard then adjust the wait time after the DgnEngine line about 12 lines from the bottom of the script (currently set to 0.7). Finally just to clarify you will get Sean's version working if you simply change the line mentioned above but the version of the script below is faster.

' tested in Dragon NaturallySpeaking 10.1 pro
' modified by Lindsay Adam March 2010
' (however active window mouse position commands only work
' if active window is positioned in top left-hand corner of primary monitor
' , this is error of original script (other active window script available from LA)
' Position your mouse pointer, say "mouse position macro"
' Select click and positiong options from the dialog box
' the macro will be coded and ready for naming
'
'
'(c)2005 Sean Wenzel All rights reserved.
' <http://sean.wenzel.net/voicerecognition/>  <http://sean.wenzel.net/voicerecognition/>
'
' This code is released under the following license:
'
' <http://www.gnu.org/copyleft/gpl.html>  <http://www.gnu.org/copyleft/gpl.html>
'

' the group to create the macro in
Const MGROUP = "MyMouse"
' Declare data types and other structures
'
' structure to hold a point
'
Public Type POINTAPI
x As Long
y As Long
End Type
Dim xcoord As String
' API forward declarations
' get the current cursor position
Declare Function GetCursorPos Lib "user32" _
Alias "GetCursorPos" (lpPoint As POINTAPI) As Long

'Declare Function GetCursorPos Lib "user32" (lpPoint As POINTAPI) As Long
'
' Display a message in the Dragon status bar
'
Function DragonMsg(s As String)
EngineControl.DragonBar.ShowMessage showmessageNoBeep, s
End Function
Sub Main
Dim p As POINTAPI
Dim macro As String
Dim s As String
' get current mouse position
GetCursorPos p
' create the options dialog
Begin Dialog UserDialog 360,273,"Create mouse macro" ' %GRID:10,7,1,1
GroupBox 20,14,320,112,"Position is relative to",.GroupBox1
OptionGroup .Group1
OptionButton 40,35,230,14,"upper-left corner of screen",.opt0
OptionButton 40,56,280,14,"upper-left corner of active window",.opt1
OptionButton 40,77,270,14,"current pointer position",.opt2
OptionButton 40,98,280,14,"upper-left corner of the window interior",.opt5
GroupBox 20,133,190,112,"Click button",.GroupBox2
OptionGroup .Group2
OptionButton 40,154,160,14,"position mouse only ",.optClickNone
OptionButton 40,175,150,14,"left click",.optClickLeft
OptionButton 40,196,140,14,"right click",.optClickRight
OptionButton 40,217,150,14,"middle click",.optClickMiddle
GroupBox 220,133,120,63,"Click type",.GroupBox3
OptionGroup .Group3
OptionButton 230,154,90,14,"Single",.optClickSingle
OptionButton 230,175,90,14,"Double",.optClickDouble
OKButton 230,203,90,21
CancelButton 230,231,90,21
Text 20,252,110,14,"Coordinates are: ",.Text1
Text 140,252,90,14,Str(p.x)+","+Str(p.y),.lblCoord
End Dialog
Dim dlg As UserDialog
dlg.Group1 = 0
dlg.Group2 = 0
dlg.Group3 = 0
If Dialog(dlg) = -1 Then
DragonMsg "Creating mouse macro... Position is: " + Str(p.x) + ", " + Str(p.y)
' build the advanced scripting macro
macro = "SetMousePosition "
' position relative to...
s = "0"
Select Case dlg.Group1
Case 0
s = "0"
Case 1
s = "1"
Case 2
s = "2"
Case 3
s = "5"
End Select
macro = macro + s + ", " + Str(p.x) + ", " + Str(p.y)
' click?
If dlg.Group2 > 0 Then
macro = macro + "{Enter}"
Select Case dlg.Group2
Case 1
s = "1"
Case 2
s = "2"
Case 3
s = "4"
End Select
macro = macro + "ButtonClick " + s
If dlg.Group3 = 0 Then
macro = macro + ", 1"
Else
macro = macro + ", 2"
End If
End If
' display the add new command wizard
' you may have to adjust the wait times below
EngineControl.DlgShow(dgndlgNewCommandWizard, 0, , 0)
Wait 0.7
SendKeys" %y"
Wait 0.2
SendKeys"{Down 3}{Tab 2}"
Wait 0.2
SendKeys macro
Wait 0.2
SendKeys"%u"
Wait 0.2
SendKeys MGROUP
Wait 0.2
SendKeys"%c"
DragonMsg "Provide a name and description for your macro."
Else
DragonMsg "Mouse position macro creation cancelled"
End If
End Sub